Pascal 日和 ホームページ

/////////////////////////////////////////////////////////////////////////////
//
// ヘッダファイル windres.h のインクルード
//

#include "windres.h"

/////////////////////////////////////////////////////////////////////////////
//
// 本ファイルのコードページ
//

#pragma code_page(65001)    // Free Pascalの{$CODEPAGE UTF8}と同じようなもの。

/////////////////////////////////////////////////////////////////////////////
//
// リソースの言語(日本語リソース)
//

LANGUAGE LANG_JAPANESE, SUBLANG_DEFAULT

/////////////////////////////////////////////////////////////////////////////
//
// バージョン情報データ (この値を編集する) ※変数は任意の名前で作成したもの。
//
// この情報データはフィクションであり、実在の人物・団体とは一切関係ありません。
//

#define VER_FILEVERSION           1,0,0,1   // ファイルバージョン
#define VER_FILEVERSION_STR       "1.0.0.1" // ファイルバージョン(文字列)

#define VER_PRODUCTVERSION        1,0,0,0   // 製品バージョン
#define VER_PRODUCTVERSION_STR    "1.0.0"   // 製品バージョン(文字列)

#define VS_FFI_FILEFLAGSMASK      0x3FL     // ファイルフラグマスク
#define VER_FFLAGS                0L        // ファイルフラグ

#define VER_FILETYPE              VFT_APP   // アプリ(EXE)。DLLの場合VFT_DLL

#define VER_COMPANYNAME_STR       "超力ソフト"               // 会社名
#define VER_FILEDESCRIPTION_STR   "ObjectPascalプログラム"   // ファイルの説明
#define VER_INTERNALNAME_STR      "Project1"                 // 内部名
#define VER_LEGALCOPYRIGHT_STR    "©2025 CHOURIKI-SOFT Inc." // 著作権表示
#define VER_LEGALTRADEMARKS_STR   ""                         // 商標/登録商標
#define VER_ORIGINALFILENAME_STR  "Project1.exe"             // オリジナル名
#define VER_PRODUCTNAME_STR       "超力アプリ"               // 製品名
#define VER_COMMENTS_STR          "バージョン情報テスト"     // 追加情報

/////////////////////////////////////////////////////////////////////////////
//
// バージョン情報定義
//

VS_VERSION_INFO VERSIONINFO
    FILEVERSION    VER_FILEVERSION
    PRODUCTVERSION VER_PRODUCTVERSION
    FILEFLAGSMASK  VS_FFI_FILEFLAGSMASK
    FILEFLAGS      VER_FFLAGS
    FILEOS         VOS_NT_WINDOWS32
    FILETYPE       VFT_APP
    FILESUBTYPE    VFT2_UNKNOWN
BEGIN
    BLOCK "StringFileInfo"
    BEGIN
        BLOCK "041104B0"  // 0x0411(日本語), 0x04B0(=1200 ユニコード)
        BEGIN
            VALUE "CompanyName",      VER_COMPANYNAME_STR
            VALUE "FileDescription",  VER_FILEDESCRIPTION_STR
            VALUE "FileVersion",      VER_FILEVERSION_STR
            VALUE "InternalName",     VER_INTERNALNAME_STR
            VALUE "LegalCopyright",   VER_LEGALCOPYRIGHT_STR
            VALUE "LegalTrademarks",  VER_LEGALTRADEMARKS_STR
            VALUE "OriginalFilename", VER_ORIGINALFILENAME_STR
            VALUE "ProductName",      VER_PRODUCTNAME_STR
            VALUE "ProductVersion",   VER_PRODUCTVERSION_STR
            VALUE "Comments",         VER_COMMENTS_STR
        END
    END
    BLOCK "VarFileInfo"
    BEGIN
        VALUE "Translation", 0x411, 1200  // 日本語, ユニコード
    END
END

program Project1;

{$MODE OBJFPC}{$H+}{$J-}
{$MINFPCONSTPREC 64}
{$CODEPAGE UTF8}

uses
  SysUtils, FileInfo;

var
  VerInfo     : TVersionInfo;
  FileVerInfo : TFileVersionInfo;

{$R VerInfo.rc}

begin

  SetMultiByteConversionCodePage(CP_UTF8);
  SetMultiByteRTLFileSystemCodePage(CP_UTF8);

  try
    VerInfo     := TVersionInfo.Create;           // 「FILEVERSION」の情報。
    FileVerInfo := TFileVersionInfo.Create(Nil);  // 「BLOCK "StringFileInfo"」の情報。
    try
      VerInfo.Load(HINSTANCE);  // バージョン情報リソースがないと例外が発生する。
    except
      WriteLn;
      WriteLn('エラー: バージョン情報がありません。');
      ExitCode := 1;
      Exit;
    end;
    WriteLn;
    { 「FILEVERSION」の情報を出力 }
    with VerInfo.FixedInfo do
    begin
      WriteLn(
        ExtractFileName(ParamStr(0)), ' Ver.',
        FileVersion[0], '.',
        FileVersion[1], '.',
        FileVersion[2], '.',
        FileVersion[3]
      );
    end;
    WriteLn;;
    { 「BLOCK "StringFileInfo"」の情報を出力 }
    FileVerInfo.ReadFileInfo;
    with FileVerInfo.VersionStrings do
    begin
      WriteLn('Company           : ', Values['CompanyName']);
      WriteLn('File description  : ', Values['FileDescription']);
      WriteLn('File version      : ', Values['FileVersion']);
      WriteLn('Internal name     : ', Values['InternalName']);
      WriteLn('Legal copyright   : ', Values['LegalCopyright']);
      WriteLn('Legal trademarks  : ', Values['LegalTrademarks']);
      WriteLn('Original filename : ', Values['OriginalFilename']);
      WriteLn('Product name      : ', Values['ProductName']);
      WriteLn('Product version   : ', Values['ProductVersion']);
      WriteLn('Comments          : ', Values['Comments']);
    end;
    WriteLn;
  finally
    FileVerInfo.Free;
    VerInfo.Free;
  end;

end.